Windows 10 21H1으로 업데이트 하는 방법

Windows 10 은 2004에서는 Feature Pack 설치로 20H2로 업그레이드가 가능했습니다. 또한 비공식이긴 하지만 2004또는 20H2에서 Windows 10 21H1으로 업데이트가 가능합니다. 누적업데이트 또한 동일하게 사용가능합니다. 두가지 방법을 알아 보겠습니다.

Windows 10 21H1으로 업데이트

첫째, 누적업데이트에 포함된 mum 파일 이용

2020년 2월 누적업에트가 적용되어 있어야만 할수 있다고 합니다. 이미 누적업데이트에 포함을 시키기 시작한듯 합니다.

윈도우 내부에 누적업데이트가 설치되면서 같이 배포가 된 파일들이 있습니다. 아래 경로에 가면 찾아보실수 있습니다.

C:\Windows\servicing\Packages

파일들이 굉장히 많이 있습니다. 이중에서 우리가 필요로 하는 파일은 아래와 같이 검색하시면 나옵니다. 명령 프롬프트 관리자 권한으로 실행해서 아래같이 명령어를 입력합니다.

dir /b C:\Windows\servicing\Packages\microsoft-windows-*-21h1-ekb-*.mum

검색된 결과 값이 아래와 같이 나올 것입니다. 여기서 아래 그림처럼 4개의 파일만 필요로 합니다. 19041.870이 포함된 4개 파일입니다.

2021 03 27 221146

4개의 파일을 dism을 이용해서 패키지추가 명령어로 통합을 해주면 됩니다.

Windows 10 21H1으로 업데이트 배치파일

위와 같이 일일히 수작업을 하는것보다 배치파일로 만들어서 하는것이 편합니다. 배치파일의 명령 구문은 윈포의 s**님의 글을 참조했습니다. 재부팅은 필요 없습니다. 바로 적용됩니다.

::https://soohyunet.com/
::by soohyunet
@prompt $s
@color 1f
@cd /d %~dp0
@title Windows 10 21H1 업데이트
@mode con cols=80 lines=25
@setlocal enabledelayedexpansion

@echo 관리자권한 확인용 >%windir%\admin.confirm || @(
echo Set UAC = CreateObject^("Shell.Application"^) > "%tmp%\admin.vbs"
echo UAC.ShellExecute "%~0", "", "", "runas", 1 >> "%tmp%\admin.vbs"
"%tmp%\admin.vbs" & del "%tmp%\admin.vbs" & exit)
@del %windir%\admin.confirm

@echo.
@echo.
@echo.
@echo.
@echo.
@echo.
@echo      Windows 10 21H1 버전으로 업데이트를 시작하시려면 아무키나 누루세요. 
@pause > nul
cls

for /f %%a in ('"Dism /Online /Get-Packages /Format:Table /English | find /i "RollupFix" | find /i "installed""') do set RollupFix=%%a
for /f "tokens=2 delims=." %%a in ("%RollupFix%") do set RollupFix_revision=%%a
for /f "tokens=*" %%a in ('dir /a-d /b %Windir%\servicing\Packages\microsoft-windows-*-21h1-ekb-*.%RollupFix_revision%*.mum') do Dism /Online /Add-package:%Windir%\servicing\Packages\%%a
goto exit

:exit 
cls
@echo.
@echo.
@echo.
@echo      Windows 10 21H1 버전으로 업데이트가 종료 되었습니다. 
@echo      버전 확인창을 띄운후 종료 합니다. 
@pause > nul
@echo off 
start winver & exit

▶ 누적업데이트를 이용한 Windows 10 21H1으로 업데이트 배치파일 다운로드

이전 빌드로 복원 배치파일

이전 빌드로 복원하시려면 아래처럼 추가한 패키지를 dism 명령어로 삭제해주시면 됩니다. 배치 파일 내용입니다. 재부팅은 필요 없습니다. 바로 적용됩니다.

::https://soohyunet.com/
::by soohyunet
@prompt $s
@color 1f
@cd /d %~dp0
@title Windows 10 21H1 업데이트
@mode con cols=80 lines=25
@setlocal enabledelayedexpansion

@echo 관리자권한 확인용 >%windir%\admin.confirm || @(
echo Set UAC = CreateObject^("Shell.Application"^) > "%tmp%\admin.vbs"
echo UAC.ShellExecute "%~0", "", "", "runas", 1 >> "%tmp%\admin.vbs"
"%tmp%\admin.vbs" & del "%tmp%\admin.vbs" & exit)
@del %windir%\admin.confirm

@echo.
@echo.
@echo.
@echo.
@echo.
@echo.
@echo      Windows 10 21H1 업데이트를 삭제하시려면 아무키나 누루세요. 
@pause > nul
cls

for /f %%a in ('"Dism /Online /Get-Packages /Format:Table /English | find /i "21h1-ekb""') do DISM.exe /Online /Remove-Package /PackageName:%%a /norestart
goto exit

:exit 
cls
@echo.
@echo.
@echo.
@echo.
@echo.
@echo.
@echo      Windows 10 21H1 업데이트가 삭제가 완료 되었습니다. 
@echo      버전 확인창을 띄운후 종료 합니다. 
@pause > nul
@echo off 
start winver & exit

▶이전 빌드로 복원 배치파일 다운로드

둘째, KB5000736.cab 파일을 이용한 업데이트

마찬가지로 2021년 2월 누적업데이트부터 제 기능을 한다고 합니다. dism으로 패키지를 추가 삭제 하면 됩니다. 아래는 기종별 KB5000736.cab 파일 다운로드 입니다. zip압축입니다. msu 파일도 추가해서 올려드립니다. ms 링크이며, 사용법은 동일합니다.

기종별 KB5000736.cab

기종별 KB5000736.msu

블로그에서 다운로드해서 바로 적용되는 배치파일 스크립트

파워쉘과 명령프롬프트 조합으로 만들어 봤습니다. 재부팅 해야 적용됩니다. 64비트 윈도우용입니다.

::https://soohyunet.com/
::by soohyunet
@prompt $s
@color 1f
@cd /d %~dp0
@title Windows 10 21H1 업데이트 두번째
@mode con cols=80 lines=25
@setlocal enabledelayedexpansion

@echo 관리자권한 확인용 >%windir%\admin.confirm || @(
echo Set UAC = CreateObject^("Shell.Application"^) > "%tmp%\admin.vbs"
echo UAC.ShellExecute "%~0", "", "", "runas", 1 >> "%tmp%\admin.vbs"
"%tmp%\admin.vbs" & del "%tmp%\admin.vbs" & exit)
@del %windir%\admin.confirm


cls
@echo.
@echo.
@echo.
@echo.
@echo           KB5000736 패키지를 이용한 Windows 10 21H1 업데이트를 
@echo           시작하시려면 아무키나 입력하세요.
@echo.
@echo.
@echo.
@echo.
@echo.
@pause > nul
powershell -executionpolicy --command "wget -Uri https://soohyunet.com/wp-content/uploads/2021/03/windows10.0-kb5000736-x64.cab.zip -OutFile $env:TEMP\windows10.0-kb5000736-x64.cab.zip"
powershell -executionpolicy --command "Expand-Archive -LiteralPath $env:TEMP\windows10.0-kb5000736-x64.cab.zip -DestinationPath $env:TEMP"
Dism /online /Add-Package /PackagePath:%TEMP%\windows10.0-kb5000736-x64.cab /norestart
@del /f /q %temp%\windows10.0-kb5000736-x64.cab
@del /f /q %temp%\windows10.0-kb5000736-x64.cab.zip
cls
@echo.
@echo.
@echo.
@echo.
@echo           바로 재부팅해서 적용하시려면 아무키나 누루세요. 
@echo.
@echo.
@echo.
@echo.
@echo.
@pause > nul
@shutdown /r /f /t 0
@exit

▶ KB5000736 패키지를 이용한 Windows 10 21H1 업데이트 배치파일 다운로드

만약 이전 버전으로 원복을 하고 싶으시다면 아래처럼 명령어 한줄 입력 하시고 재부팅 하시면 됩니다.

DISM.exe /Online /Remove-Package /PackageName:Package_for_KB5000736~31bf3856ad364e35~amd64~~10.0.1.2

참고

Leave a Comment